From 7899a8e8717b5c5b0b92e7fda9bd7c3366a5ad22 Mon Sep 17 00:00:00 2001
From: Moritz Gmeiner <moritz@gmeiner.net>
Date: Sat, 3 Jan 2026 15:50:01 +0100
Subject: [PATCH] fuzzel: 1.13.1

---
 gui-apps/fuzzel/Manifest             |  1 +
 gui-apps/fuzzel/fuzzel-1.13.1.ebuild | 57 ++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 gui-apps/fuzzel/fuzzel-1.13.1.ebuild

diff --git a/gui-apps/fuzzel/Manifest b/gui-apps/fuzzel/Manifest
index 09bec63..e70790d 100644
--- a/gui-apps/fuzzel/Manifest
+++ b/gui-apps/fuzzel/Manifest
@@ -1 +1,2 @@
 DIST fuzzel-1.12.0.tar.gz 480171 BLAKE2B 075d10974516b149f0c2d602947b2c338e710be20e57e8524b0f51ddaad8c53d8bfb95e68c8d4ec15f0a1601c15f1ca46cfc247a30f658f69865e7773a384113 SHA512 c7d25f46ac064d2cf6875c3e138a23a8120b1f01e2de64b08939009f9575dd96fa252ef3747a63daff5c7454b560795f3930111440c90b44c49aa3f157217021
+DIST fuzzel-1.13.1.tar.gz 501037 BLAKE2B 01fd39d40661edc06872c31738aa5af4fc18ae71438b7e61e7987099dea4706438ca36008982bdab7a64fb1448ebb612ac5cb3d6e8aa43df90c3597522184d66 SHA512 dea1dd056df4928ffad08991149224d21a7aaa430de62dffb31601419cfae3ad420fdb8fe607a6d5ee8fd58c14024ea3d8249dc6c02fa68c0f38b60038de06be
diff --git a/gui-apps/fuzzel/fuzzel-1.13.1.ebuild b/gui-apps/fuzzel/fuzzel-1.13.1.ebuild
new file mode 100644
index 0000000..3a65dae
--- /dev/null
+++ b/gui-apps/fuzzel/fuzzel-1.13.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="https://codeberg.org/dnkl/fuzzel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="png svg"
+
+DEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.0.0
+	media-libs/fontconfig
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	png? ( media-libs/libpng )
+	svg? ( media-libs/nanosvg )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	>=dev-libs/wayland-protocols-1.32
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg nanosvg none)
+		$(meson_feature svg system-nanosvg)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}
+
+pkg_postinst() {
+	optfeature "For rounded corner support" x11-libs/cairo
+}